view CMakeLists.txt @ 4:34a7a99dbcfa

Switch to Boost.Test
author David Demelier <markand@malikania.fr>
date Fri, 01 Dec 2017 16:46:31 +0100
parents 0d9603b420c2
children ebcc8c9c8831
line wrap: on
line source

#
# CMakeLists.txt -- unicode module
#
# Copyright (c) 2013-2017 David Demelier <markand@malikania.fr>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#

cmake_minimum_required(VERSION 3.5)
project(unicode CXX)

set(CMAKE_CXX_STANDARD 14)
set(CMAKE_CXX_STANDARD_REQUIRED On)

set(UNICODE_VERSION_MAJOR "1")
set(UNICODE_VERSION_MINOR "0")
set(UNICODE_VERSION_PATCH "0")
set(UNICODE_VERSION "${UNICODE_VERSION_MAJOR}.${UNICODE_VERSION_MINOR}.${UNICODE_VERSION_PATCH}-dev")

find_package(Doxygen QUIET)
find_package(Boost REQUIRED COMPONENTS unit_test_framework)

add_subdirectory(generator)

enable_testing()
add_executable(
    unicode
    ${unicode_SOURCE_DIR}/unicode.cpp
    ${unicode_SOURCE_DIR}/unicode.hpp
    ${unicode_SOURCE_DIR}/test/main.cpp
    ${unicode_SOURCE_DIR}/INSTALL.md
    ${unicode_SOURCE_DIR}/LICENSE.md
    ${unicode_SOURCE_DIR}/README.md
)
target_link_libraries(unicode Boost::unit_test_framework)
target_include_directories(unicode PRIVATE ${unicode_SOURCE_DIR})
target_compile_definitions(unicode PRIVATE BOOST_TEST_DYN_LINK)
add_test(unicode unicode)

if (DOXYGEN_FOUND)
    if (NOT DOXYGEN_DOT_FOUND)
        set(DOXYGEN_HAVE_DOT "NO")
        set(DOXYGEN_DOT_PATH "")
    else ()
        set(DOXYGEN_HAVE_DOT "YES")
        set(DOXYGEN_DOT_PATH "\"${DOXYGEN_DOT_EXECUTABLE}\"")
    endif ()

    configure_file(
        ${unicode_SOURCE_DIR}/doc/Doxyfile.in
        ${unicode_BINARY_DIR}/Doxyfile
    )

    add_custom_target(
        doxygen ALL
        COMMAND ${DOXYGEN_EXECUTABLE} ${unicode_BINARY_DIR}/Doxyfile
        SOURCES
            ${unicode_SOURCE_DIR}/doc/Doxyfile.in
            ${unicode_SOURCE_DIR}/doc/mainpage.cpp
        WORKING_DIRECTORY ${unicode_SOURCE_DIR}
    )
endif ()