#
# MalikaniaDefineExecutable.cmake -- CMake build system for malikania
#
# Copyright (c) 2013-2018 David Demelier <markand@malikania.fr>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#

#
# malikania_define_executable
# ---------------------------
#
# malikania_define_executable(
#       TARGET          The target name
#       FOLDER          Specify alternate folder
#       SOURCES         The list of sources
#       FLAGS           (Optional) List of flags
#       INCLUDES        (Optional) List of include directories
#       LIBRARIES       (Optional) List of libraries
# )
#

include(${CMAKE_CURRENT_LIST_DIR}/MalikaniaBuildAssets.cmake)

function(malikania_define_executable)
	set(singleArgs FOLDER TARGET)
	set(multiArgs ASSETS SOURCES FLAGS INCLUDES LIBRARIES)

	cmake_parse_arguments(EXE "" "${singleArgs}" "${multiArgs}" ${ARGN})

	if (NOT EXE_TARGET)
		message(FATAL_ERROR "Missing TARGET parameter")
	endif ()
	if (NOT EXE_SOURCES)
		message(FATAL_ERROR "Missing SOURCES parameter")
	endif ()

	malikania_build_assets("${EXE_ASSETS}" assets)

	add_executable(${EXE_TARGET} ${EXE_SOURCES} ${EXE_ASSETS} ${assets})
	target_link_libraries(${EXE_TARGET} ${EXE_LIBRARIES})
	target_include_directories(
		${EXE_TARGET}
		PRIVATE
			${CMAKE_CURRENT_BINARY_DIR}/assets
			${EXE_INCLUDES}
	)
	target_compile_definitions(${EXE_TARGET} PRIVATE ${EXE_FLAGS})

	if (EXE_FOLDER)
		set_target_properties(${EXE_TARGET} PROPERTIES FOLDER ${EXE_FOLDER})
	endif ()
endfunction()