#
# CMakeLists.txt -- CMake build system for malikania
#
# Copyright (c) 2013-2017 Malikania Authors
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#

set(
    maps
    minimal-b64
    minimal-b64-gzip
    minimal-b64-zlib
    minimal-csv
    minimal-xml
)

foreach (m ${maps})
    add_custom_command(
        OUTPUT
            ${CMAKE_CURRENT_BINARY_DIR}/${m}.json
            ${CMAKE_CURRENT_BINARY_DIR}/${m}.map
        COMMAND
            $<TARGET_FILE:mlk-map>
                ${CMAKE_CURRENT_SOURCE_DIR}/${m}.tmx
                ${CMAKE_CURRENT_BINARY_DIR}/${m}.json
                ${CMAKE_CURRENT_BINARY_DIR}/${m}.map
        DEPENDS
            mlk-map
            ${CMAKE_CURRENT_SOURCE_DIR}/${m}.tmx
        VERBATIM
        COMMENT "Creating minimal.json and minimal.map using mlk-map(1)"
    )

    list(APPEND sources ${CMAKE_CURRENT_SOURCE_DIR}/${m}.tmx)
    list(
        APPEND
        outputs
        ${CMAKE_CURRENT_BINARY_DIR}/${m}.json
        ${CMAKE_CURRENT_BINARY_DIR}/${m}.map
    )
endforeach()

malikania_create_test(
    NAME map
    LIBRARIES json
    SOURCES
        ${sources}
        ${outputs}
        ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
)