#
# CMakeLists.txt -- CMake build system for malikania
#
# Copyright (c) 2013-2017 David Demelier <markand@malikania.fr>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#

set(
    TILESET_SOURCES
    tileset_external.tmx
    tileset_embedded.tmx
    tileset.tsx
)

#
# For each tileset in TILESET_SOURCES, generate a file named
#
# ${CMAKE_CURRENT_BINARY_DIR}/<name>.json
#
# Example:
#
#   ${CMAKE_CURRENT_BINARY_DIR}/tileset.json
#
foreach (f ${TILESET_SOURCES})
    get_filename_component(file ${f} NAME_WE)
    add_custom_command(
        OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${file}.json
        COMMAND
            $<TARGET_FILE:mlk-tileset>
                ${CMAKE_CURRENT_SOURCE_DIR}/${f}
                ${CMAKE_CURRENT_BINARY_DIR}/${file}.json
        VERBATIM
        DEPENDS
            mlk-tileset
            ${CMAKE_CURRENT_SOURCE_DIR}/${f}
        COMMENT "Generating ${file}.json"
    )
    list(APPEND TILESET_OUTPUTS ${CMAKE_CURRENT_BINARY_DIR}/${file}.json)
endforeach ()

malikania_create_test(
    NAME mlk-tileset
    LIBRARIES libmlk-common
    SOURCES
        ${TILESET_SOURCES}
        ${TILESET_OUTPUTS}
        ${CMAKE_CURRENT_SOURCE_DIR}/main.cpp
)