#
# CMakeLists.txt -- CMake build system for malikania
#
# Copyright (c) 2013-2018 David Demelier <markand@malikania.fr>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#

cmake_minimum_required(VERSION 3.0)
project(malikania)

set_property(GLOBAL PROPERTY USE_FOLDERS On)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED On)
set(CMAKE_POSITION_INDEPENDENT_CODE On)
set(CMAKE_WINDOWS_EXPORT_ALL_SYMBOLS On)
set(CMAKE_MODULE_PATH ${malikania_SOURCE_DIR}/cmake/packages)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

foreach (cfg ${CMAKE_CONFIGURATION_TYPES})
	string(TOUPPER CFG ${cfg})
	set(CMAKE_RUNTIME_OUTPUT_DIRECTORY_${CFG} ${CMAKE_BINARY_DIR}/bin/${cfg})
endforeach ()

include(cmake/function/MalikaniaBuildAssets.cmake)
include(cmake/function/MalikaniaDefineLibrary.cmake)
include(cmake/function/MalikaniaDefineExample.cmake)
include(cmake/function/MalikaniaDefineExecutable.cmake)
include(cmake/function/MalikaniaDefineTest.cmake)
include(cmake/function/MalikaniaSetg.cmake)

include(cmake/MalikaniaVersion.cmake)
include(cmake/MalikaniaOptions.cmake)
include(cmake/MalikaniaSystem.cmake)

configure_file(
	${malikania_SOURCE_DIR}/cmake/internal/sysconfig.hpp.in
	${malikania_BINARY_DIR}/sysconfig.hpp
)
include_directories(${malikania_BINARY_DIR})

find_package(Boost REQUIRED QUIET COMPONENTS filesystem system timer unit_test_framework)
find_package(OpenSSL REQUIRED)

add_subdirectory(tools)

if (MALIKANIA_WITH_EXAMPLES)
	add_subdirectory(examples)
endif ()

add_subdirectory(extern)
add_subdirectory(doc)
add_subdirectory(libmlk)

if (MALIKANIA_HAS_SERVER)
	add_subdirectory(libmlk-db)
	add_subdirectory(libmlk-server)
	add_subdirectory(mlk-server)
endif ()

if (MALIKANIA_HAS_CLIENT)
	add_subdirectory(libmlk-client)
	add_subdirectory(mlk-client)
endif ()

if (MALIKANIA_WITH_TESTS)
	if (MALIKANIA_HAS_SERVER)
		add_subdirectory(libmlk-db-test)
	endif ()

	enable_testing()
	add_subdirectory(tests)
endif ()

message("")
message("Building information:")
message("    General flags:     ${CMAKE_CXX_FLAGS}")
message("    Debug flags:       ${CMAKE_CXX_FLAGS_DEBUG}")
message("    Release flags:     ${CMAKE_CXX_FLAGS_RELEASE}")
message("")
message("Component selection:")
message("    Server:            ${MALIKANIA_HAS_SERVER_MSG}")
message("    Client:            ${MALIKANIA_HAS_CLIENT_MSG}")
message("")
message("Documentation:")
message("    HTML:              ${MALIKANIA_HAS_HTML_MSG}")
message("")
message("Additional options:")
message("    Tests:             ${MALIKANIA_HAS_TESTS_MSG}")
message("    Examples:          ${MALIKANIA_HAS_EXAMPLES_MSG}")
message("")