#
# FindZSTD.cmake -- find ZSTD C library
#
# Copyright (c) 2020 David Demelier <markand@malikania.fr>
#
# Permission to use, copy, modify, and/or distribute this software for any
# purpose with or without fee is hereby granted, provided that the above
# copyright notice and this permission notice appear in all copies.
#
# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
#
# Find ZSTD library, this modules defines:
#
# ZSTD_INCLUDE_DIRS, where to find zstd.h
# ZSTD_LIBRARIES, where to find library
# ZSTD_FOUND, if it is found
#
# The following imported targets will be available:
#
# ZSTD::ZSTD, if found.
#

find_path(ZSTD_INCLUDE_DIR NAMES zstd.h)
find_library(ZSTD_LIBRARY NAMES libzstd zstd)

include(FindPackageHandleStandardArgs)

find_package_handle_standard_args(
	ZSTD
	FOUND_VAR ZSTD_FOUND
	REQUIRED_VARS ZSTD_LIBRARY ZSTD_INCLUDE_DIR
)

if (ZSTD_FOUND)
	set(ZSTD_LIBRARIES ${ZSTD_LIBRARY})
	set(ZSTD_INCLUDE_DIRS ${ZSTD_INCLUDE_DIR})

	if (NOT TARGET ZSTD::ZSTD)
		add_library(ZSTD::ZSTD UNKNOWN IMPORTED)
		set_target_properties(
			ZSTD::ZSTD
			PROPERTIES
				IMPORTED_LINK_INTERFACE_LANGUAGES "C"
				IMPORTED_LOCATION "${ZSTD_LIBRARY}"
				INTERFACE_INCLUDE_DIRECTORIES "${ZSTD_INCLUDE_DIRS}"
		)
	endif ()
endif ()

mark_as_advanced(ZSTD_INCLUDE_DIR ZSTD_LIBRARY)